File not found error while trying to run replication .gss file

Based upon your report, my best guess is that you have a line like this in your main program file:

#include c:\gssprograms\fcst.prc

However, the file fcst.prc is actually in this director C:\Users\rar145.AUTH\Desktop\FSW Data (2)\ip\ddisk\GSS. The simplest thing to do is to:

1. Place all files in the same directory.
2. Set your GAUSS working directory to this same directory. You can use the working directory toolbar button to set the working directory.
3. Remove all paths in the program. For example, change:

   #include c:\gssprograms\fcst.prc
   

   to this:

   #include fcst.prc
   

   If there is no path, GAUSS will look in your current working directory to find the file.

I want to add this so you can see my working directory and the files in that directory:

Line 10 in C:\Users\rar145.AUTH\Desktop\FSW Data (2)\ip\ddisk\GSS\figure_1_a.gss
File not found G0014 : 'c:\gssprograms\fcst.prc'
File not found:
» cdir(0);
C:\Users\rar145.AUTH\Desktop\FSW Data (2)\ip\ddisk\GSS
» filesa("*");

.
..
avg_gamma_alpha.gss
benchmark_error_var.gss
factor.gss
factor_77.gss
factor_io.gss
factor_io_2.gss
factor_io_3.gss
factor_io_77.gss
factor_io_thetai.gss
Fcst.prc
figure_1_a.gss
gam_alpha_77.gss
gam_alpha_98.gss
getTheta98.gss
Graph_gamma_theta.gss
IPload_77.gss
IPload_98.gss
models
ols_output.txt
table_8.gss
UnivariateSummary_q.gss
»

I am getting a new g0014 error but it is for something I can't locate in the code I am trying to execute.

New error:

********

error G0014 : 'c:\ip\ddisk\gss\fmt\caldsm_98_0.fmt' : File not found

********

Here is the entire code (posted online for replication by original author):

/*
Figure_1_a
*/

new;
library pgraph;
graphset;
outwidth 256;
tilde_char="~";
#include fcst.prc;
fmtdir = "c:\\ip\\ddisk\\gss\\";
outdir = "c:\\ip\\ddisk\\gss\\";
figdir = "c:\\ip\\ddisk\\gss\\";

level=4;
split_date = 1984.0; @ Date For Split @

@ Quarterly Data -- q; monthly data m@
iperiod = 1; @ 1 for monthly, 2 for quarterly @
ag_code = 0; @ Month of quarter (1-3) or 0 = Average @
idata = 2; @ 2 for 98-NAICS, 1 for 77-SIC @

if iperiod .== 1;
pstr="m_";
scm=1200;
elseif iperiod .== 2;
pstr="q_";
scm=400;
endif;

if idata .== 1;
dstr="77_";
elseif idata .== 2;
dstr="98_";
endif;

labelstr = pstr $+ dstr $+ ftocv(ag_code,1,0);

@ Calendar @
str = fmtdir $+ "calds" $+ labelstr;
load caldsq=^str;
dnobs=rows(caldsq);
cal=caldsq[.,1]+((caldsq[.,2]-1)/(scm/100));
ismpl1=cal .< split_date-.0001;
ismpl2=cal .>= split_date-.0001;
cal1=selif(cal,ismpl1);
cal2=selif(cal,ismpl2);
@ Aggregate Data @
str = fmtdir $+ "l0" $+ labelstr;
load IP = ^str;
d_ip = miss(zeros(dnobs,1),0);
d_ip[2:dnobs]=scm*ln(ip[2:dnobs]./ip[1:dnobs-1]);

@ Graph Aggregate IP @
sdfs=stdc(packr(d_ip));
sd1=stdc(packr(selif(d_ip,ismpl1)));
sd2=stdc(packr(selif(d_ip,ismpl2)));
graphset;
cvtname=figdir $+ "IP_Growth" $+ labelstr $+ ".emf";
cmdstr="-c=8 -cf=" $+ cvtname;
/*
cvtname=figdir $+ "IP_Growth" $+ labelstr $+ ".eps";
cmdstr="-c=1 -cf=" $+ cvtname;
*/
graphprt(cmdstr);
fonts("simplex complex microb simgrma");
_pdate="";
_pmsgstr="\204s\201]" $+ ftocv(floor(cal[1]),4,0) $+ "-" $+ ftocv(floor(cal[rows(cal)]),4,0) $+ "[ = " $+ ftocv(sdfs,2,1);
_pmsgstr=_pmsgstr $+ "00\204s\201]" $+ ftocv(floor(cal1[1]),4,0) $+ "-" $+ ftocv(floor(cal1[rows(cal1)]),4,0) $+ "[ = " $+ ftocv(sd1,2,1);
_pmsgstr=_pmsgstr $+ "00\204s\201]" $+ ftocv(floor(cal2[1]),4,0) $+ "-" $+ ftocv(floor(cal2[rows(cal2)]),4,0) $+ "[ = " $+ ftocv(sd2,2,1);
if iperiod .== 2;
_pmsgctl=(1984~-13~0.15~0~1~1~0)|(1984~-16~0.15~0~1~1~0)|(1984~-19~0.15~0~1~1~0);
elseif iperiod .== 1;
_pmsgctl=(1984~-19~0.15~0~1~1~0)|(1984~-23~0.15~0~1~1~0)|(1984~-27~0.15~0~1~1~0);
endif;
_pltype=6;
_pcolor=1;
xtics(1970,2010,5,5);
xy(cal,d_ip);

Change these lines:

fmtdir = "c:\\ip\\ddisk\\gss\\";
outdir = "c:\\ip\\ddisk\\gss\\";
figdir = "c:\\ip\\ddisk\\gss\\";

They are used later to tell the program where to load certain files and save other output files. However, they are not correct for your machine. You can simply change them to an empty string if all files are in your current working directory.

fmtdir = "";
outdir = "";
figdir = "";